0

Text in Word ohne oder mit spezifischer Formatierung einfügen

Mit „Bearbeiten → Einfügen“ (+V unter MacOS; Strg+V unter Windows) lässt sich Text aus der Zwischenablage in ein Word-Dokument einfügen. Sofern der in der Zwischenablage enthaltene Text formatiert ist, wird diese Formatierung beim Einfügen in Word übernommen.

Einfügen ohne Formatierung

Häufig möchte man aber nur den Text als solchen ohne jede Formatierung einfügen.

MacOS

Unter MacOS kann man dazu auf „Bearbeiten → Inhalte einfügen“ klicken und im sich öffnenden Dialogfenster „Unformatierten Text“ auswählen:

Für einen direkten Zugriff auf diese Funktion kann man unter „Extras → Tastatur anpassen…“ bei „Kategorien:“ den Eintrag „Bearbeiten“ und bei „Befehle“ den Eintrag „NurTextEinfügen“ auswählen und diesem eine Tastenkombination zuweisen (→ dazu etwa Teil 1 unserer Einführung in Word-Makros):

Windows

Unter Windows kann man Text ohne jede Formatierung einfügen, indem man in der Registerkarte „Start“ auf den Pfeil unter „Einfügen“ klickt und dann entweder dort auf das Symbol mit dem schwarzen A („Nur den Text übernehmen (T)“) klickt oder auf der Tastatur die Taste T drückt:

Um dieser Funktion unmittelbar eine Tastenkombination zuzuweisen, klicken Sie auf „Datei“ → „Optionen“ → „Menüband anpassen“ und dann in der linken Spalte unten neben „Tastenkombinationen“ auf den Button „Anpassen…“. Im sich öffnenden Fenster wählen Sie links bei „Kategorien:“ den Eintrag „Alle Befehle“ aus und rechts bei „Befehle:“ den Eintrag „NurTextEinfügen“. Im Textfeld bei „Neue Tastenkombination:“ können Sie dann die gewünschten Tasten auf der Tastatur drücken und mit einem Klick unten links auf den Button „Zuordnen“ die Zuordnung dieser Tastenkombination bestätigen:

Wer möchte, kann unter Windows sogar einstellen, dass Text aus einer anderen Anwendung als Word auch beim Drücken von Strg+V ohne Formatierung eingefügt wird. Für diese Einstellung hat man auf „Datei“ → „Optionen“ → „Erweitert“ zu klicken und dort in der Rubrik „Ausschneiden, Kopieren und Einfügen“ im Auswahlfeld bei „Einfügen aus anderen Programmen“ die Option „Nur den Text übernehmen“ zu wählen:

Einfügen mit spezifischer Formatierung

Bisweilen kann es aber umgekehrt nötig sein, den einzufügenden Text gerade in einer bestimmten Weise zu formatieren. Wird beispielsweise die Fundstelle eines Literaturzitats aus der Zwischenablage eingefügt, die vor dem ersten Komma den Namen der Autorin oder des Autors enthält (etwa „Feiler, Kollisionsrecht der Vertragsübernahme, 2019“), kann es gewollt sein, diesen Namen kursiv oder unterstrichen darzustellen („Feiler, Kollisionsrecht der Vertragsübernahme, 2019″ oder „Feiler, Kollisionsrecht der Vertragsübernahme, 2019″). Ein derartiger Inhalt der Zwischenablage kann zum Beispiel aus einer Literatur- oder Dateiverwaltung stammen oder aus einem im Browser geöffneten Juris- oder Beck-Online-Dokument.

Mithilfe eines Word-Makros lässt sich Derartiges leicht bewerkstelligen. Falls Sie unsicher sind, wie Sie in Word Makros erstellen und verwenden können, empfehlen wir unsere Einführung in Word-Makros.

Aufgaben und Logik des Makros

  • Zunächst soll der Inhalt der Zwischenablage in eine Variable (Zwischenablage) eingelesen werden, um ihn so weiterverarbeiten zu können.
  • Sodann wird geprüft, ob in dem Text ein Komma enthalten ist. Wenn dies nicht der Fall ist, wird eine Warnung angezeigt, kein Text in das Dokument eingefügt und das Makro abgebrochen.
  • Der Teil des Textes bis zum ersten Komma wird in eine Variable (AutorInnenNamen) kopiert, der Teil des Textes nach dem ersten Komma in eine andere Variable (RestlicherText).
  • An der Stelle des Cursors wird die Schrift auf kursiv umgestellt und es wird der Inhalt der Variable AutorInnenNamen geschrieben. Dann wird die Schrift auf nicht kursiv zurückgestellt und es werden ein Komma sowie der Inhalt der Variable RestlicherText geschrieben.

Nötige Befehle

Hinweis: Sie müssen die Befehle nicht im Einzelnen verstehen, um das Makro verwenden zu können. Für einen Einstieg in die Grundsätze des Makro-Programmierens empfehlen wir Teil III unserer Einführung in Word-Makros.

 

  • Der Inhalt der Zwischenablage kann mittels GetFromClipboard auf einem MSForms.DataObject ausgelesen werden. GetText übernimmt dabei den unformatierten Text
    • Hinweis: Um MSForms.DataObject verwenden zu können, muss in Ihrem Visual-Basic-Editor die nötige Bibliothek aktiviert sein. Klicken Sie dazu im Visual-Basic-Editor auf „Extras“ → „Verweise“ und setzen Sie das Häkchen bei „Microsoft Forms 2.0 Object Library“:
  • InStr(String1, String2) sucht im ersten String-Argument nach dem ersten Vorkommen des zweiten String-Arguments und gibt die Nummer des Zeichens im ersten String-Argument zurück, ab welcher das zweite String-Argument beginnt. Die Rückgabe 0 bedeutet, dass der zu suchende String nicht gefunden wurde.
  • Split(String2, String2, Integer) zerschneidet einen Text an vorgegebenen Stellen. Das erste String-Argument ist der zu bearbeitende String, das zweite String-Argument gibt an, an welcher Stelle im ersten String-Argument der Schnitt erfolgen soll. Das dritte Integer-Argument bedeutet, in wie viele Teile der Text maximal zerschnitten werden soll. Da wir nur am ersten Komma schneiden wollen und weitere Kommata keine Rolle spielen sollen, ist hier 2 anzugeben. Der Rückgabewert von Split ist ein Array, also eine Reihe von Werten, wobei der erste Wert die Position 0 hat. Indem wir hinter dem Split-Befehl in runden Klammern eine 0 oder eine 1 angeben, können wir auf das erste oder das zweite Element des Arrays zugreifen.

Komplettes Makro

Sub TextBisErstesKommaKursivEinfuegen()
    Dim ClipBoard As MSForms.DataObject
    Dim ZwischenAblage As String
    Dim AutorInnenNamen As String
    Dim RestlicherText As String

    ' Kopieren des Inhalts der Zwischenablage in eine
    ' String-Variable
    Set ClipBoard = New MSForms.DataObject
    ClipBoard.GetFromClipboard
    ZwischenAblage = ClipBoard.GetText

    ' Abbruch des Makros mit Warnung, wenn
    ' kein Komma vorhanden
    If InStr(ZwischenAblage, ",") = 0 Then
        MsgBox "Der einzufügende Text enthält kein " _
            & "Komma und wird daher nicht eingefügt."
        Exit Sub
    End If

    ' Trennung des einzufügenden Texts am ersten Komma
    ' und Speichern in String-Variablen
    AutorInnenNamen = Split(ZwischenAblage, ",", 2)(0)
    RestlicherText = Split(ZwischenAblage, ",", 2)(1)

    Selection.Font.Italic = True
    Selection.TypeText (AutorInnenNamen)

    Selection.Font.Italic = False
    Selection.TypeText (",")
    Selection.TypeText (RestlicherText)
End Sub

Anpassungs- und Erweiterungsmöglichkeiten

Anstelle von Font.Italic kann auch Font.Bold oder Font.Underline verwendet werden. Ferner kann beispielsweise bei Rechtsprechungszitaten der zwischen runden Klammern stehende Entscheidungsname kursiv geschrieben werden. Möchte man für Literatur- und Rechtsprechungszitate ein einheitliches Makros verwenden, kann dieses zunächst überprüfen, ob vor dem ersten Komma ein Gericht genannt wird.

Schreibe einen Kommentar

Es gelten die üblichen Spielregeln. Der Name wird veröffentlicht, die E-Mail-Adresse nicht. Bitte freundlich und sachbezogen bleiben.